Fargelegg rader og kolonner

Ved hjelp av makroene nedenfor kan man angi en bakgrunnsfarge til f.eks. annen hver rad eller kolonne i et angitt regnearkområde. Makroene er også et godt utgangspunkt dersom man trenger å lage sine egne makroer som skal formatere eller endre innhold i et regnearkområde.

Sub ShadeAlternateRows(rngTarget As Range, intColor As Integer, lngStep As Long)
' benytter bakgrunnsfargen = intColor på hver lngStep rad i rngTarget
' eksempel: ShadeAlternateRows Range("A1:D50"), 27, 2 
' fargelegger annen hver rad
Dim r As Long
    If rngTarget Is Nothing Then Exit Sub
    With rngTarget
        .Interior.ColorIndex = xlColorIndexNone 
        ' fjern eventuell eksisterende farge
        For r = lngStep To .Rows.Count Step lngStep
            .Rows(r).Interior.ColorIndex = intColor
        Next r
    End With
End Sub

Sub ShadeAlternateColumns(rngTarget As Range, intColor As Integer, lngStep As Long)
' benytter bakgrunnsfargen = intColor på hver lngStep kolonne i rngTarget
' eksempel: ShadeAlternateColumns Range("A1:J20"), 27, 2 
' fargelegger annen hver kolonne
Dim c As Long
    If rngTarget Is Nothing Then Exit Sub
    With rngTarget
        .Interior.ColorIndex = xlColorIndexNone 
        ' fjern eventuell eksisterende farge
        For c = lngStep To .Columns.Count Step lngStep
            .Columns(c).Interior.ColorIndex = intColor
        Next c
    End With
End Sub

Man kan merke et regnearkområde og velge Format, Betinget formatering og fylle inn dialogen slik eksempelet nedenfor viser for å angi en bakgrunnsfarge til annen hver rad:

Den norske formelen skal se slik ut: =HVIS(REST(RAD();2)=0;SANN;USANN)

Man kan merke et regnearkområde og velge Format, Betinget formatering og fylle inn dialogen slik eksempelet nedenfor viser for å angi en bakgrunnsfarge til annen hver kolonne:

Den norske formelen skal se slik ut: =HVIS(REST(KOLONNE();2)=0;SANN;USANN)

Dokumentet er sist oppdatert 2002-07-17 12:37:25

Brukerkommentarer:

Ole P. fra Trondheim skrev (2006-08-24 08:53:27 CET):

Re: norsk
Norsk VBA (eller VBA i en annen språkdrakt) kunne benyttes i Excel 5 (og muligens Excel 95).
Dette støttes ikke lengre, det ble for tungvint å distribuere språkfiler som var nødvendig for at f.eks. en norsk løsning skulle fungere i Tyskland.
I dag er man nødt til å programmere med engelsk VBA.

De to siste dialogene i eksempelet ovenfor har ikke noe med VBA å gjøre, de viser hvordan man kan oppnå en tilsvarende løsning med innebygget funksjonalitet i Excel.
Dersom man skal fylle inn formler i Excel med VBA er det anbefalt at man fyller inn formlene på engelsk, det er mulig å fylle inn formler med VBA i det lokale språket (f.eks. norsk), men da vil ikke løsningen fungere i andre språkversjoner av Excel.

Ole P. fra Trondheim skrev (2006-08-24 08:47:21 CET):

Re: sann og usann
Det er ikke noe problem å benytte Sann og Usann i formlene i Excel.
Excel oversetter dette automatisk slik at formlene vil være gyldige dersom løsningen åpnes i en annen språkversjon av Excel.

kt skrev (2006-08-24 02:25:42 CET):

norsk
er det virkelig noen som bruker norsk vba?

kt skrev (2006-08-24 02:23:33 CET):

sann og usann
Dersom regnearket skal kunne brukes av excel i forskjellig språkdrakt er det vel heller bedre å bruke "1" for "sann" og "0" for "usann"?