Spille lydnotater

I Excel 5 og 95 kan man knytte merknader til en celle i form av en lydfil. Lydnotatet kan avspilles ved at man tar frem dialogen for redigering av cellemerknaden. Ved hjelp av makroen nedenfor kan man spille av lydmerknaden til en angitt celle:

Sub PlaySoundNotesInExcel95(CellAddress As String)
' for Excel 5 and 95 only
    If Not Application.CanPlaySounds Then Exit Sub
    On Error Resume Next ' i tilfelle det ikke finnes noe lydnotat
    Range(CellAddress).SoundNote.Play
    On Error GoTo 0
End Sub

Excel 97 eller senere støtter ikke lengre bruk av lydnotater. Ved hjelp av makroene nedenfor er det allikevel mulig å få til en tilsvarende effekt:

Public Declare Function sndPlaySound Lib "winmm.dll" _
Alias "sndPlaySoundA" (ByVal lpszSoundName As String, _
ByVal uFlags As Long) As Long


Sub PlayWavFile(WavFileName As String, Wait As Boolean)
    If Dir(WavFileName) = "" Then Exit Sub ' ingen fil
    If Wait Then ' spill lyden før koden fortsetter å kjøre
        sndPlaySound WavFileName, 0
    Else ' spill lyden mens koden fortsetter å kjøre
        sndPlaySound WavFileName, 1
    End If
End Sub


Sub PlaySoundNotesInExcel97(CellAddress As String)
' spiller lydmerknader i Excel 97 eller senere
Dim SoundFileName As String
    SoundFileName = ""
    On Error Resume Next ' feil oppstår dersom cellen ikke har en merknad
    SoundFileName = Range(CellAddress).Comment.Text
    On Error GoTo 0
    If SoundFileName = "" Then Exit Sub ' ingen merknad
    If InStr(1, SoundFileName, Chr(10)) > 0 Then ' merknaden inneholder et linjeskift
        ' bruk den første linjen som filnavn
        SoundFileName = Left(SoundFileName, InStr(1, SoundFileName, Chr(10)) - 1)
    End If
    PlayWavFile SoundFileName, False
End Sub

For å lage et lydnotat gjør du følgende:
Sett inn en cellemerknad ved å høyreklikke på en celle og velge Sett inn merknad....
Den første setningen i cellemerknaden fylles inn med det komplette navnet til lydfilen som skal avspilles, f.eks. C:\Mappenavn\Lydfilnavn.wav.
Dersom du vil legge til en skriftlig merknad i tillegg til navnet på lydfilen trykker du på ENTER-tasten etter filnavnet slik at du får en ny linje i merknaden, deretter kan du fortsette å fylle inn den teksten du vil ha.
Makroen PlaySoundNotesInExcel97 kan f.eks. aktiveres av hendelsesmakroen Worksheet_SelectionChange(), da vil lydnotatet avspilles med en gang brukeren aktiverer cellen med lydnotatet.

Dokumentet er sist oppdatert 1999-08-13 12:36:15 Utskriftsvennlig versjon